ईमेल के बाहर, शायद सबसे आम तरीका हैकिसी दूरस्थ पार्टी को फ़ाइलें FTP के माध्यम से भेजें। जबकि एफ़टीपी ग्राहकों के ढेर सारे विकल्प हैं जिनसे आप चुन सकते हैं, विंडोज़ में थोड़ी ज्ञात और उपयोग की जाने वाली कमांड लाइन एफ़टीपी यूटिलिटी है। इस टूल की सुंदरता इसमें लिपिबद्ध होने की क्षमता है जो हमने नीचे दी गई बैच स्क्रिप्ट में लिखी है।
इस स्क्रिप्ट का उपयोग कमांड लाइन से किया जा सकता हैor कोई प्रश्न नहीं पूछा 'एक ही आदेश के साथ एक या कई फ़ाइलों को अपलोड करने का तरीका। इसके अतिरिक्त, आप स्वचालित फ़ाइल अपलोड करने के लिए बैच स्क्रिप्ट से इस स्क्रिप्ट को कॉल कर सकते हैं। इसके लिए कुछ उपयोग शामिल हैं (लेकिन, निश्चित रूप से, सीमित नहीं):
- डेटा स्क्रिप्ट भेजने के लिए बैकअप स्क्रिप्ट में शामिल करें।
- HTML / php / etc अपलोड करें। एक ही आदेश के साथ एक वेब सर्वर के लिए फ़ाइलें।
- फ़ाइलों का एक सामान्य समूह (जैसे वेब साइट के स्रोत पृष्ठ) भेजने के लिए शॉर्टकट बनाएँ।
विन्यास
एफ़टीपी सर्वर कनेक्शन जानकारी सेट करने के लिए केवल आवश्यक कॉन्फ़िगरेशन है। "कनेक्शन जानकारी" लाइन के तहत, निम्नलिखित सेट करें:
- सर्वर - जिस FTP सर्वर पर आप अपलोड कर रहे हैं। आप या तो DNS नाम (ftp.myserver.com) या IP पता (1.2.3.4) दर्ज कर सकते हैं।
- UserName - FTP सर्वर से कनेक्ट करने के लिए आपका उपयोगकर्ता नाम।
- पासवर्ड - एफ़टीपी सर्वर से कनेक्ट करने के लिए आपका पासवर्ड।
आपकी फ़ायरवॉल सेटिंग्स के आधार पर, पहलाजब आप इस स्क्रिप्ट को चलाते हैं तो आपको एफ़टीपी को इंटरनेट से कनेक्ट करने की अनुमति देने के लिए प्रेरित किया जा सकता है। भविष्य में चेतावनी को दूर करने के लिए इसे फिर से शुरू नहीं करना चाहिए।
लिपी
@ECHO OFF
ECHO Upload to FTP
ECHO Written by: Jason Faulkner
ECHO SysadminGeek.com
ECHO.
ECHO.
REM Usage:
REM UploadToFTP [/L] FileToUpload
REM
REM Required Parameters:
REM FileToUpload
REM The file or file containing the list of files to be uploaded.
REM
REM Optional Parameters:
REM /L When supplied, the FileToUpload is read as a list of files to be uploaded.
REM A list of files should be a plain text file which has a single file on each line.
REM Files listed in this file must specify the full path and be quoted where appropriate.
SETLOCAL EnableExtensions
REM Connection information:
SET Server=
SET UserName=
SET Password=
REM ---- Do not modify anything below this line ----
SET Commands="%TEMP%SendToFTP_commands.txt"
REM FTP user name and password. No spaces after either.
ECHO %UserName%> %Commands%
ECHO %Password%>> %Commands%
REM FTP transfer settings.
ECHO binary >> %Commands%
IF /I {%1}=={/L} (
REM Add file(s) to the list to be FTP'ed.
FOR /F "usebackq tokens=*" %%I IN ("%~dpnx2") DO ECHO put %%I >> %Commands%
) ELSE (
ECHO put "%~dpnx1" >> %Commands%
)
REM Close the FTP connection.
ECHO close >> %Commands%
ECHO bye >> %Commands%
REM Perform the FTP.
FTP -d -i -s:%Commands% %Server%
ECHO.
ECHO.
REM Clean up.
IF EXIST %Commands% DEL %Commands%
ENDLOCAL
लिंक
Sysadmin Geek से FTP स्क्रिप्ट में अपलोड डाउनलोड करें
