Ārpus e-pasta, iespējams, visizplatītākais veidsnosūtīt failus uz attālo pusi notiek caur FTP. Lai gan ir daudz FTP klientu, no kuriem jūs varat izvēlēties, operētājsistēmā Windows ir iebūvēta komandrindas FTP utilīta, kas ir maz pazīstama un tiek izmantota. Šī rīka skaistums slēpjas tā spējā būt skriptiem, kurus mēs esam izmantojuši tālāk esošajā sērijas skriptā.
Šo skriptu no komandrindas var izmantot kāmetode “nav uzdoti jautājumi”, lai ar vienu komandu augšupielādētu vienu vai vairākus failus. Turklāt, lai veiktu automatizētu failu augšupielādi, jūs varat izsaukt šo skriptu no sērijveida failiem. Daži no šiem lietojumiem ietver (bet, protams, ne tikai):
- Iekļaujiet rezerves skriptos, lai nosūtītu datus ārpus uzņēmuma.
- Augšupielādēt html / php / utt. failus Web serverī ar vienu komandu.
- Izveidojiet saīsnes, lai nosūtītu kopēju failu grupu (piemēram, vietnes avota lapas).
Konfigurācija
Vienīgā nepieciešamā konfigurācija ir FTP servera savienojuma informācijas iestatīšana. Zem līnijas “Savienojuma informācija” iestatiet:
- Serveris - FTP serveris, kurā jūs augšupielādējat. Varat ievadīt DNS vārdu (ftp.myserver.com) vai IP adresi (1.2.3.4).
- Lietotājvārds - jūsu lietotājvārds savienojuma izveidei ar FTP serveri.
- Parole - jūsu parole savienojuma izveidei ar FTP serveri.
Pirmais atkarībā no ugunsmūra iestatījumiemšo skriptu palaižot, jums var tikt lūgts atļaut FTP izveidot savienojumu ar internetu. Ja iestatīsit šo režīmu tā, lai tas vairs nekad netiktu parādīts, turpmākie brīdinājumi ir jānoņem.
Scenārijs
@ECHO OFF
ECHO Upload to FTP
ECHO Written by: Jason Faulkner
ECHO SysadminGeek.com
ECHO.
ECHO.
REM Usage:
REM UploadToFTP [/L] FileToUpload
REM
REM Required Parameters:
REM FileToUpload
REM The file or file containing the list of files to be uploaded.
REM
REM Optional Parameters:
REM /L When supplied, the FileToUpload is read as a list of files to be uploaded.
REM A list of files should be a plain text file which has a single file on each line.
REM Files listed in this file must specify the full path and be quoted where appropriate.
SETLOCAL EnableExtensions
REM Connection information:
SET Server=
SET UserName=
SET Password=
REM ---- Do not modify anything below this line ----
SET Commands="%TEMP%SendToFTP_commands.txt"
REM FTP user name and password. No spaces after either.
ECHO %UserName%> %Commands%
ECHO %Password%>> %Commands%
REM FTP transfer settings.
ECHO binary >> %Commands%
IF /I {%1}=={/L} (
REM Add file(s) to the list to be FTP'ed.
FOR /F "usebackq tokens=*" %%I IN ("%~dpnx2") DO ECHO put %%I >> %Commands%
) ELSE (
ECHO put "%~dpnx1" >> %Commands%
)
REM Close the FTP connection.
ECHO close >> %Commands%
ECHO bye >> %Commands%
REM Perform the FTP.
FTP -d -i -s:%Commands% %Server%
ECHO.
ECHO.
REM Clean up.
IF EXIST %Commands% DEL %Commands%
ENDLOCAL
Saites
Lejupielādējiet augšupielādi FTP skriptā no Sysadmin Geek
